<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/08/24/setting-the-volume-on-a-videodisplay-control-in-flex/ -->
<mx:Application name="VideoDisplay_volume_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
         layout="vertical"
         verticalAlign="middle"
         backgroundColor="white"
         initialize="init();">

    <mx:Script>
        <![CDATA[
            import mx.containers.ApplicationControlBar;
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.controls.Button;
            import mx.controls.HSlider;
            import mx.controls.VideoDisplay;
            import mx.controls.sliderClasses.Slider;
            import mx.events.SliderEvent;
            import mx.events.VideoEvent;

            private var slider:HSlider;
            private var videoDisplay:VideoDisplay;
            private var playBtn:Button;

            private function init():void {
                slider = new HSlider();
                slider.minimum = 0.0;
                slider.maximum = 1.0;
                slider.value = 0.7; /* 70% */
                slider.snapInterval = 0.01;
                slider.tickInterval = 0.1;
                slider.liveDragging = true;
                slider.addEventListener(SliderEvent.CHANGE, slider_change);

                videoDisplay = new VideoDisplay();
                videoDisplay.source = "http://www.helpexamples.com/flash/video/cuepoints.flv";
                videoDisplay.volume = slider.value;
                videoDisplay.autoPlay = false;
                videoDisplay.addEventListener(VideoEvent.PLAYHEAD_UPDATE, videoDisplay_playheadUpdate);

                playBtn = new Button();
                playBtn.label = "Play";
                playBtn.enabled = !videoDisplay.playing;
                playBtn.addEventListener(MouseEvent.CLICK, playBtn_click);

                var formItem:FormItem = new FormItem();
                formItem.label = "volume:";
                formItem.addChild(slider);

                var form:Form = new Form();
                form.styleName = "plain";
                form.addChild(formItem);

                var appControlBar:ApplicationControlBar;
                appControlBar = new ApplicationControlBar();
                appControlBar.dock = true;
                appControlBar.addChild(form);
                Application.application.addChildAt(appControlBar, 0);

                addChild(videoDisplay);
                addChild(playBtn);
            }

            private function slider_change(evt:SliderEvent):void {
                videoDisplay.volume = evt.value;
            }

            private function playBtn_click(evt:MouseEvent):void {
                videoDisplay.play();
            }

            private function videoDisplay_playheadUpdate(evt:VideoEvent):void {
                playBtn.enabled = !videoDisplay.playing;
            }
        ]]>
    </mx:Script>

</mx:Application>