<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/03/19/horizontally-aligning-tabs-within-a-tabbar-control-in-flex/ -->
<mx:Application name="TabBar_horizontalAlign_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">

    <mx:Script>
        <![CDATA[
            import mx.containers.BoxDirection;
            import mx.containers.Box;
            import mx.containers.ApplicationControlBar;
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.controls.TabBar;
            import mx.controls.ComboBox;
            import mx.events.ListEvent;

            private var arr:Array;
            private var comboBox:ComboBox;
            private var tabBar:TabBar;

            private function init():void {
                arr = [];
                arr.push({label:"Button"});
                arr.push({label:"ButtonBar"});
                arr.push({label:"ColorPicker"});
                arr.push({label:"ComboBox"});

                var dp:Array = [];
                dp.push({label:"left"});
                dp.push({label:"center"});
                dp.push({label:"right"});

                comboBox = new ComboBox();
                comboBox.dataProvider = dp;
                comboBox.addEventListener(ListEvent.CHANGE,
                            comboBox_change);

                var formItem:FormItem = new FormItem();
                formItem.label = "horizontalAlign:";
                formItem.addChild(comboBox);

                var form:Form = new Form();
                form.styleName = "plain";
                form.addChild(formItem);

                var appControlBar:ApplicationControlBar;
                appControlBar = new ApplicationControlBar();
                appControlBar.dock = true;
                appControlBar.addChild(form);
                addChildAt(appControlBar, 0)

                tabBar = new TabBar();
                tabBar.dataProvider = arr;
                tabBar.width = 600;
                tabBar.setStyle("tabWidth", 100);
                tabBar.setStyle("tabHeight", 40);
                tabBar.direction = BoxDirection.HORIZONTAL;

                var box:Box = new Box();
                box.setStyle("backgroundColor", "haloSilver");
                box.addChild(tabBar);
                addChild(box);
            }

            private function comboBox_change(evt:ListEvent):void {
                tabBar.setStyle("horizontalAlign",
                            comboBox.selectedItem.label);
            }
        ]]>
    </mx:Script>

</mx:Application>