<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/08/16/creating-an-undraggable-titlewindow-container-in-flex/ -->
<mx:Application name="PopUpManager_TitleWindow_isPopUp_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white">

    <mx:Script>
        <![CDATA[
            import mx.containers.ControlBar;
            import mx.controls.ButtonLabelPlacement;
            import mx.controls.CheckBox;
            import mx.containers.TitleWindow;
            import mx.controls.Label;
            import mx.core.ContainerLayout;
            import mx.events.CloseEvent;
            import mx.events.FlexEvent;
            import mx.managers.PopUpManager;

            private var checkBox:CheckBox;
            private var titleWin:TitleWindow;

            private function launch():void {
                var lbl:Label = new Label();
                lbl.text = "Drag this window";
                lbl.setStyle("horizontalCenter", 0);
                lbl.setStyle("verticalCenter", 0);
                
                checkBox = new CheckBox();
                checkBox.label = "isPopUp:";
                checkBox.labelPlacement = ButtonLabelPlacement.LEFT;
                checkBox.selected = true;
                checkBox.addEventListener(Event.CHANGE, checkBox_change);

                var controlBar:ControlBar = new ControlBar();
                controlBar.addChild(checkBox);

                titleWin = new TitleWindow();
                titleWin.layout = ContainerLayout.ABSOLUTE;
                titleWin.title = "TitleWindow";
                titleWin.showCloseButton = true;
                titleWin.width = 300;
                titleWin.height = 200;
                titleWin.addChild(lbl);
                titleWin.addChild(controlBar);
                titleWin.addEventListener(CloseEvent.CLOSE, titleWin_close);
                PopUpManager.addPopUp(titleWin, this, true);
                PopUpManager.centerPopUp(titleWin);
            }

            private function titleWin_close(evt:CloseEvent):void {
                PopUpManager.removePopUp(titleWin);
            }

            private function checkBox_change(evt:Event):void {
                titleWin.isPopUp = checkBox.selected;
            }
        ]]>
    </mx:Script>

    <mx:ApplicationControlBar dock="true">
        <mx:Button id="btn"
                label="Launch TitleWindow PopUp"
                click="launch();" />
    </mx:ApplicationControlBar>

</mx:Application>