<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/07/17/changing-the-background-color-of-a-disabled-list-control-in-flex/ -->
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">

    <mx:Script>
        <![CDATA[
            import mx.containers.ApplicationControlBar;
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.controls.CheckBox;
            import mx.controls.ColorPicker;
            import mx.controls.List;
            import mx.events.ColorPickerEvent;

            private var arr:Array;
            private var checkBox:CheckBox;
            private var colorPicker:ColorPicker;
            private var list:List;

            private function init():void {
                arr = [];
                arr.push({label:"One"});
                arr.push({label:"Two"});
                arr.push({label:"Three"});
                arr.push({label:"Four"});
                arr.push({label:"Five"});
                arr.push({label:"Six"});
                arr.push({label:"Seven"});
                arr.push({label:"Eight"});
                arr.push({label:"Nine"});
                arr.push({label:"Ten"});

                checkBox = new CheckBox();
                checkBox.selected = true;
                checkBox.addEventListener(Event.CHANGE, checkBox_change);

                colorPicker = new ColorPicker();
                colorPicker.selectedColor = 0xDDDDDD;
                colorPicker.addEventListener(ColorPickerEvent.CHANGE, colorPicker_change);

                var formItem1:FormItem = new FormItem();
                formItem1.label = "enabled:";
                formItem1.addChild(checkBox);

                var formItem2:FormItem = new FormItem();
                formItem2.label = "backgroundDisabledColor:";
                formItem2.addChild(colorPicker);

                var form:Form = new Form();
                form.styleName = "plain";
                form.addChild(formItem1);
                form.addChild(formItem2);

                var appControlBar:ApplicationControlBar;
                appControlBar = new ApplicationControlBar();
                appControlBar.dock = true;
                appControlBar.addChild(form);
                Application.application.addChildAt(appControlBar, 0);

                list = new List();
                list.dataProvider = arr;
                list.width = 200;
                addChild(list);
            }

            private function checkBox_change(evt:Event):void {
                list.enabled = checkBox.selected;
            }

            private function colorPicker_change(evt:ColorPickerEvent):void {
                list.setStyle("backgroundDisabledColor", evt.color);
            }
        ]]>
    </mx:Script>

</mx:Application>