<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/09/06/setting-the-vertical-gap-between-an-icon-and-label-on-a-linkbutton-control-in-flex/ -->
<mx:Application name="LinkButton_verticalGap_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">

    <mx:Script>
        <![CDATA[
            import mx.containers.ApplicationControlBar;
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.controls.ButtonLabelPlacement;
            import mx.controls.ComboBox;
            import mx.controls.HSlider;
            import mx.controls.LinkButton;
            import mx.events.ListEvent;
            import mx.events.SliderEvent;

            [Embed("assets/LinkButton.png")]
            private const linkButtonIcon:Class;

            private var slider:HSlider;
            private var comboBox:ComboBox;
            private var linkButton:LinkButton;

            private function init():void {
                var arr:Array = [];
                arr.push(ButtonLabelPlacement.TOP);
                arr.push(ButtonLabelPlacement.BOTTOM);

                slider = new HSlider();
                slider.minimum = 0;
                slider.maximum = 10;
                slider.value = 2;
                slider.snapInterval = 1;
                slider.tickInterval = 1;
                slider.liveDragging = true;
                slider.addEventListener(SliderEvent.CHANGE,
                            slider_change);

                comboBox = new ComboBox();
                comboBox.dataProvider = arr;
                comboBox.addEventListener(ListEvent.CHANGE,
                            comboBox_change);

                var formItem1:FormItem = new FormItem();
                formItem1.label = "verticalGap:";
                formItem1.addChild(slider);

                var formItem2:FormItem = new FormItem();
                formItem2.label = "labelPlacement:";
                formItem2.addChild(comboBox);

                var form:Form = new Form();
                form.styleName = "plain";
                form.addChild(formItem1);
                form.addChild(formItem2);

                var appControlBar:ApplicationControlBar;
                appControlBar = new ApplicationControlBar();
                appControlBar.dock = true;
                appControlBar.addChild(form);
                addChildAt(appControlBar, 0);

                linkButton = new LinkButton();
                linkButton.label = "LinkButton";
                linkButton.labelPlacement = ButtonLabelPlacement.TOP;
                linkButton.setStyle("icon", linkButtonIcon);
                addChild(linkButton);
            }

            private function slider_change(evt:SliderEvent):void {
                linkButton.setStyle("verticalGap", evt.value);
            }

            private function comboBox_change(evt:ListEvent):void {
                var value:String = comboBox.selectedItem.toString();
                linkButton.labelPlacement = value;
            }
        ]]>
    </mx:Script>

</mx:Application>