<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/09/06/creating-a-toggleable-linkbutton-control-in-flex/ -->
<mx:Application name="LinkButton_toggle_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">

    <mx:Script>
        <![CDATA[
            import skins.ToggleLinkButtonSkin;

            import mx.containers.ApplicationControlBar;
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.controls.CheckBox;
            import mx.controls.LinkButton;

            private var toggleCheckBox:CheckBox;
            private var selectedCheckBox:CheckBox;
            private var linkButton:LinkButton;

            private function init():void {
                toggleCheckBox = new CheckBox();
                toggleCheckBox.addEventListener(Event.CHANGE,
                            toggleCheckBox_change);

                selectedCheckBox = new CheckBox();
                selectedCheckBox.addEventListener(Event.CHANGE,
                            selectedCheckBox_change);

                var formItem1:FormItem = new FormItem();
                formItem1.label = "toggle:";
                formItem1.addChild(toggleCheckBox);

                var formItem2:FormItem = new FormItem();
                formItem2.label = "selected:";
                formItem2.addChild(selectedCheckBox);

                var form:Form = new Form();
                form.styleName = "plain";
                form.addChild(formItem1);
                form.addChild(formItem2);

                var appControlBar:ApplicationControlBar;
                appControlBar = new ApplicationControlBar();
                appControlBar.dock = true;
                appControlBar.addChild(form);
                addChildAt(appControlBar, 0);

                linkButton = new LinkButton();
                linkButton.label = "LinkButton";
                linkButton.setStyle("skin", ToggleLinkButtonSkin);
                linkButton.addEventListener(Event.CHANGE,
                            linkButton_change);
                addChild(linkButton);
            }

            private function toggleCheckBox_change(evt:Event):void {
                linkButton.toggle = toggleCheckBox.selected;
            }

            private function selectedCheckBox_change(evt:Event):void {
                linkButton.selected = selectedCheckBox.selected;
            }

            private function linkButton_change(evt:Event):void {
                selectedCheckBox.selected = linkButton.selected;
            }
        ]]>
    </mx:Script>

</mx:Application>