<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/09/27/setting-the-label-placement-on-a-legend-control-in-flex/ -->
<mx:Application name="Legend_labelPlacement_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">

    <mx:Script>
        <![CDATA[
            import mx.charts.Legend;
            import mx.charts.PieChart;
            import mx.charts.series.PieSeries;
            import mx.collections.XMLListCollection;
            import mx.containers.ApplicationControlBar;
            import mx.containers.ControlBar;
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.containers.Panel;
            import mx.containers.TileDirection;
            import mx.controls.ButtonLabelPlacement;
            import mx.controls.ComboBox;
            import mx.events.ListEvent;

            private var directionCB:ComboBox;
            private var dp:XMLListCollection;
            private var labelPlacementCB:ComboBox;
            private var legend:Legend;
            private var panel:Panel;
            private var pieChart:PieChart;
            private var pieSeries:PieSeries;

            private function init():void {
                var data:XML = <products>
                            <product label="Product 1" data="3" />
                            <product label="Product 2" data="1" />
                            <product label="Product 3" data="4" />
                            <product label="Product 4" data="1" />
                            <product label="Product 5" data="5" />
                            <product label="Product 6" data="9" />
                        </products>;

                dp = new XMLListCollection(data.product);

                var directionDP:Array = [];
                directionDP.push({label:TileDirection.HORIZONTAL});
                directionDP.push({label:TileDirection.VERTICAL});

                directionCB = new ComboBox();
                directionCB.dataProvider = directionDP;
                directionCB.addEventListener(ListEvent.CHANGE,
                            directionCB_change);

                var labelPlacementDP:Array = [];
                labelPlacementDP.push({label:ButtonLabelPlacement.LEFT});
                labelPlacementDP.push({label:ButtonLabelPlacement.RIGHT});
                // labelPlacementDP.push({label:ButtonLabelPlacement.TOP});
                // labelPlacementDP.push({label:ButtonLabelPlacement.BOTTOM});

                labelPlacementCB = new ComboBox();
                labelPlacementCB.dataProvider = labelPlacementDP;
                labelPlacementCB.selectedIndex = 1;
                labelPlacementCB.addEventListener(ListEvent.CHANGE,
                            labelPlacementCB_change);

                var formItem1:FormItem = new FormItem();
                formItem1.label = "direction:";
                formItem1.addChild(directionCB);

                var formItem2:FormItem = new FormItem();
                formItem2.label = "labelPlacement:";
                formItem2.addChild(labelPlacementCB);

                var form:Form = new Form();
                form.styleName = "plain";
                form.addChild(formItem1);
                form.addChild(formItem2);

                var appControlBar:ApplicationControlBar;
                appControlBar = new ApplicationControlBar();
                appControlBar.dock = true;
                appControlBar.addChild(form);
                addChildAt(appControlBar, 0);

                pieSeries = new PieSeries();
                pieSeries.field = "@data";
                pieSeries.nameField = "@label";
                pieSeries.filters = [];

                pieChart = new PieChart();
                pieChart.dataProvider = dp;
                pieChart.percentWidth = 100;
                pieChart.percentHeight = 100;
                pieChart.series = [pieSeries];

                legend = new Legend();
                legend.dataProvider = pieChart;
                legend.direction = TileDirection.HORIZONTAL;
                legend.percentWidth = 100;
                legend.setStyle("horizontalGap", 100);

                var controlBar:ControlBar = new ControlBar();
                controlBar.addChild(legend);

                panel = new Panel();
                panel.styleName = "opaquePanel";
                panel.percentWidth = 100;
                panel.percentHeight = 100;
                panel.addChild(pieChart);
                panel.addChild(controlBar);
                addChild(panel);
            }

            private function directionCB_change(evt:ListEvent):void {
                legend.direction = directionCB.value.toString();
            }

            private function labelPlacementCB_change(evt:ListEvent):void {
                legend.setStyle("labelPlacement", labelPlacementCB.value);
            }
        ]]>
    </mx:Script>

</mx:Application>