<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/10/21/setting-the-ligature-level-on-an-fxtextinput-control-in-flex-gumbo/ -->
<Application name="FxTextInput_ligatureLevel_test"
        xmlns="http://ns.adobe.com/mxml/2009"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();">

    <Script>
        <![CDATA[
            import flash.text.engine.FontLookup;
            import flash.text.engine.LigatureLevel;

            import mx.components.FxTextInput;
            import mx.containers.ApplicationControlBar;
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.controls.ToggleButtonBar;
            import mx.events.ItemClickEvent;

            [Embed(source="assets/ACaslonPro-Regular.otf",
                        fontFamily="AdobeCaslonProEmbedded",
                        cff="true",
                        unicodeRange="U+0020-U+007B",
                        mimeType="application/x-font")]
            private const MyEmbeddedFont:Class;

            private var toggleButtonBar:ToggleButtonBar;
            private var fxTextInput:FxTextInput;
            private var arr:Array;

            private function init():void {
                arr = [];
                arr.push(LigatureLevel.COMMON);
                arr.push(LigatureLevel.EXOTIC);
                arr.push(LigatureLevel.MINIMUM);
                arr.push(LigatureLevel.NONE);
                arr.push(LigatureLevel.UNCOMMON);

                toggleButtonBar = new ToggleButtonBar();
                toggleButtonBar.dataProvider = arr;
                toggleButtonBar.addEventListener(ItemClickEvent.ITEM_CLICK, toggleButtonBar_itemClick);

                var formItem:FormItem = new FormItem();
                formItem.label = "ligatureLevel:";
                formItem.addChild(toggleButtonBar);
                
                var form:Form = new Form();
                form.styleName = "plain";
                form.addChild(formItem);
                
                var appControlBar:ApplicationControlBar;
                appControlBar = new ApplicationControlBar();
                appControlBar.dock = true;
                appControlBar.addChild(form);
                addChildAt(appControlBar, 0);

                fxTextInput = new FxTextInput();
                fxTextInput.text = "fi fj fl ft ffi ffj ffl ct st Th";
                fxTextInput.setStyle("fontFamily", "AdobeCaslonProEmbedded");
                fxTextInput.setStyle("fontSize", 48);
                fxTextInput.setStyle("fontLookup", FontLookup.EMBEDDED_CFF);
                addChild(fxTextInput);
            }

            private function toggleButtonBar_itemClick(evt:ItemClickEvent):void {
                fxTextInput.setStyle("ligatureLevel", evt.item);
            }
        ]]>
    </Script>

</Application>