<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/11/26/creating-a-solid-color-fill-on-an-ellipse-object-in-flex-gumbo/ -->
<FxApplication name="Ellipse_fill_solidColor_test"
        xmlns="http://ns.adobe.com/mxml/2009"
        initialize="init();">
    <layout>
        <BasicLayout />
    </layout>

    <Script>
        <![CDATA[
            import mx.containers.Form;
            import mx.containers.FormItem;
            import mx.controls.ColorPicker;
            import mx.controls.HSlider;
            import mx.events.ColorPickerEvent;
            import mx.events.SliderEvent;
            import mx.graphics.Ellipse;
            import mx.graphics.SolidColor;

            private var colorPicker:ColorPicker;
            private var slider:HSlider;
            private var ellipse:Ellipse;
            private var solidColor:SolidColor;

            private function init():void {
                colorPicker = new ColorPicker();
                colorPicker.selectedColor = 0x000000; // black
                colorPicker.addEventListener(ColorPickerEvent.CHANGE, colorPicker_change);

                slider = new HSlider();
                slider.minimum = 0.0; // 0%
                slider.maximum = 1.0; // 100%
                slider.value = 1.0;
                slider.snapInterval = 0.1;
                slider.tickInterval = 0.1;
                slider.liveDragging = true;
                slider.addEventListener(SliderEvent.CHANGE, slider_change);

                var formItem1:FormItem = new FormItem();
                formItem1.label = "color:";
                formItem1.addChild(colorPicker);

                var formItem2:FormItem = new FormItem();
                formItem2.label = "alpha:";
                formItem2.addChild(slider);

                var form:Form = new Form();
                form.addChild(formItem1);
                form.addChild(formItem2);
                addItem(form);

                solidColor = new SolidColor();

                ellipse = new Ellipse();
                ellipse.width = 300;
                ellipse.height = 200;
                ellipse.horizontalCenter = 0;
                ellipse.verticalCenter = 0;
                ellipse.fill = solidColor;
                addItem(ellipse);
            }

            private function colorPicker_change(evt:ColorPickerEvent):void {
                solidColor.color = evt.color;
            }

            private function slider_change(evt:SliderEvent):void {
                solidColor.alpha = evt.value;
            }
        ]]>
    </Script>

</FxApplication>