<?xml version="1.0" encoding="utf-8"?>
<!-- http://blog.flexexamples.com/2008/10/12/aligning-the-header-text-in-a-datagrid-column-in-flex-redux/ -->
<mx:Application name="DataGrid_textAlign_test"
        xmlns:mx="http://www.adobe.com/2006/mxml"
        layout="vertical"
        verticalAlign="middle"
        backgroundColor="white"
        initialize="init();"
        viewSourceURL="srcview/index.html">

    <mx:Script>
        <![CDATA[
            import mx.utils.ObjectUtil;
            import mx.controls.Alert;
            import mx.controls.DataGrid;
            import mx.controls.dataGridClasses.DataGridColumn;
            import mx.rpc.events.FaultEvent;
            import mx.rpc.events.ResultEvent;
            import mx.rpc.http.HTTPService;

            private var dataGrid:DataGrid;
            private var httpServ:HTTPService;

            private function init():void {
                var centerAlignBold:CSSStyleDeclaration;
                centerAlignBold = new CSSStyleDeclaration(".centerAlignDataGridCol");
                centerAlignBold.setStyle("textAlign", TextFormatAlign.CENTER);
                centerAlignBold.setStyle("fontWeight", "bold");
                
                var dataGridCol1:DataGridColumn = new DataGridColumn("@colA");
                var dataGridCol2:DataGridColumn = new DataGridColumn("@colB");
                var dataGridCol3:DataGridColumn = new DataGridColumn("@colC");
                dataGridCol3.setStyle("headerStyleName", "centerAlignDataGridCol");
                dataGridCol3.setStyle("textAlign", TextFormatAlign.RIGHT);

                var cols:Array = [];
                cols.push(dataGridCol1);
                cols.push(dataGridCol2);
                cols.push(dataGridCol3);

                dataGrid = new DataGrid();
                dataGrid.columns = cols;
                addChild(dataGrid);

                httpServ = new HTTPService();
                httpServ.url = "data/items.xml";
                httpServ.resultFormat = "e4x";
                httpServ.addEventListener(ResultEvent.RESULT, httpServ_result);
                httpServ.addEventListener(FaultEvent.FAULT, httpServ_fault);
                httpServ.send();
            }
            
            private function httpServ_result(evt:ResultEvent):void {
                dataGrid.dataProvider = XML(httpServ.lastResult).item;
            }

            private function httpServ_fault(evt:FaultEvent):void {
                Alert.show("Failed to load: " + evt.currentTarget.url, evt.fault.faultString);
            }
        ]]>
    </mx:Script>

</mx:Application>