I’ve wanted to implement the same thing and I’ve done this by adding a custom effect to a class extending Image called sourceChangingEffect. The component shouldn’t be named Photo but in this case I was using it to display Photo objects. Feel to try it out. I’m not sure if I have it completely spot on but some testing shows it works well.

package com.arc90.fresh.controls
{
    import flash.events.Event;

    import mx.controls.Image;
    import mx.core.mx_internal;
    import mx.effects.EffectManager;
    import mx.events.EffectEvent;
    import mx.styles.StyleManager;

    use namespace mx_internal;

    //--------------------------------------
    //  Effects
    //--------------------------------------

    /**
     * Played when the source is changed but before it is replaced with
     * the new provided source.
     */
    [Effect(name="sourceChangingEffect", event="sourceChanging")]

    /**
     *
     */
    public class Photo extends Image
    {
        //-----------------------------------------------------------------
        //
        //  Class variables
        //
        //-----------------------------------------------------------------

        /**
         * @private
         * Trigger when static instance is created to set defaults.
         */
        private static var classConstructed:Boolean = constructClass();

        //-----------------------------------------------------------------
        //
        //  Class methods
        //
        //-----------------------------------------------------------------

        /**
         * @private
         * Triggered to run when static instance is created so defaults
         * are set.
         */
        private static function constructClass():Boolean
        {
            EffectManager.registerEffectTrigger("sourceChangingEffect", "sourceChanging");

            return true;
        }

        //-----------------------------------------------------------------
        //
        //  Variables
        //
        //-----------------------------------------------------------------

        /**
         * Storage for the boolean indicating that a sourceChangingEffect the new
         * the new been specified.
         */
        protected var hasSourceChangingEffect:Boolean = false;

        /**
         * Storage for the new source property value. When a
         * sourceChangingEffect style is defined we need to temporarily
         * store the new source before actually committing it. Once the
         * effect is done then we commit the new source value.
         */
        protected var newSource:Object;

        //-----------------------------------------------------------------
        //
        //  Constructor
        //
        //-----------------------------------------------------------------

        /**
         * Constructor.
         */
        public function Photo()
        {
            super();
        }

        //-----------------------------------------------------------------
        //
        //  Overridden properties
        //
        //-----------------------------------------------------------------

        //----------------------------------
        //  source
        //----------------------------------

        /**
         * @private
         */
        private var sourceChanged:Boolean = false;

        /**
         * @private
         */
        override public function set source(value:Object):void
        {
            if (value == source)
                return;

            // if we made it this far then we have changed the source, if
            // we'vebeen given a sourceChangingEffect style then we need
            // to wait before committing the new source value
            if (StyleManager.isValidStyleValue(getStyle("sourceChangingEffect")))
            {
                if (isEffectStarted)
                {
                    removeEventListener(EffectEvent.EFFECT_END, effectEndHandler);
                    endEffectsStarted();
                }

                // if source wasn't defined then we are setting it for the
                // first time
                if (!source)
                    super.source = value;
                else
                {
                    hasSourceChangingEffect = true;

                    addEventListener(EffectEvent.EFFECT_END, effectEndHandler);

                    dispatchEvent(new Event("sourceChanging"));
                }
            }
            else // otherwise we work as we would normally, just commit new value
            {
                hasSourceChangingEffect = false;
                removeEventListener(EffectEvent.EFFECT_END, effectEndHandler);

                super.source = value;
            }

            newSource = value;
        }

        //-----------------------------------------------------------------
        //
        //  Event handler
        //
        //-----------------------------------------------------------------

        /**
         * @private
         */
        private function effectEndHandler(event:EffectEvent):void
        {
            removeEventListener(EffectEvent.EFFECT_END, effectEndHandler);

            if (hasSourceChangingEffect)
            {
                // now that our effect has finished commit the new source,
                // the parent (SWFLoader) takes care of everything we need
                super.source = newSource;
            }
        }
    }
}

where can I find the value for effects? such as you used in your script “Face”