/**
* Whenever data or external sort criteria change, call this method. It will
* resort the pending list by simulating a mouseclick (headRelease event), triggering
* a sortColumn() call.
*
* The normal method of sorting (creating a SortField) does not respect the sortCompareFunction
* rules and does not pop up the little arrow on the column(s) being sorted; this does.
* */
private function setDefaultPendingSort():void {

// Adobe's "textbook" way to sort columns doesn't respect custom column sorting,
// and will not display the arrow when sorting on multiple columns:
//model.sampleList.sort = new Sort();
//model.sampleList.sort.fields = [new SortField("emp_name", true,false,true), new SortField("emp_id",true,false,true)];
//model.sampleList.refresh();

// The MUCH better way simulates a mouseclick on the header...

var defaultColumn:String = "emp_name"; //"accessionNum";
var col:DataGridColumn = getColumnByDataField(dgPendingSamples, defaultColumn);
col.sortDescending = false;

var dgEvent:DataGridEvent = new DataGridEvent("headerRelease");
dgEvent.dataField = defaultColumn;
dgEvent.columnIndex = getColumnIndexByDataField(dgPendingSamples, defaultColumn);
dgEvent.rowIndex = -1;
dgPendingSamples.dispatchEvent(dgEvent);

}

/**
* Returns the column based on the column's data field. Returns the first column found that
* uses the specified dataField, or -1 if none found.
* */
private function getColumnIndexByDataField(dg:DataGrid, dfld:String):int {
for (var i:uint = 0; i < dg.columnCount; i++) {
var col:DataGridColumn = dg.columns[i];
if(col.dataField == dfld) {
return i;
}
}
return -1;
}

/**
* Returns the column based on the header text, allowing
* columns to be rearranged without fucking up column dependencies.
* Returns null if none match.
* */
private function getColumnByDataField(dg:DataGrid, dfld:String):DataGridColumn {
for (var i:uint = 0; i < dg.columnCount; i++) {
var col:DataGridColumn = dg.columns[i];
if(col.dataField == dfld) {
return col;
}
}
return null;
}